⑴ 51單片機做數字電子鍾
源程序如下： ORG 0000H ;程序開始入口
LJMP START
ORG 0003H ;外中斷0中斷程序入口
RETI
ORG 000BH ;定時器T0中斷程序入口
LJMP INTT0 ;跳至INTTO執行
ORG 0013H ;外中斷1中斷程序入口
RETI
ORG 001BH ;定時器T1中斷程序入口
LJMP INTT1
ORG 0023H ;串列中斷程序入口地址
RETI
;---------------主程序----------------------;
START:MOV R0,#70H ;70給R0,清70-7FH顯示內存
MOV R7,#0FH
CLEARDISP:MOV @R0,#00H ;0給R0中的數為地址的內存中存放(70H)
INC R0
DJNZ R7,CLEARDISP
MOV 78H,#2 ;默認時間為12:00,鬧鍾5:00
MOV 79H,#1
MOV 74H,#2 ;防止上電時數碼管顯示00小時
MOV 75H,#1
MOV 66H,#1 ;中斷退出時66H為1時,分、時計時單元數據移入顯存標志
MOV 68H,#1 ;上電默認鬧鍾開狀態
MOV 7DH,#6 ;鬧鍾時十位
MOV 7CH,#3
MOV 69H,#0
MOV 7AH,#0AH ;放入"熄滅符"數據
MOV TMOD,#11H ;設T0、T1為16位定時器
MOV TL0,#0B0H ;50MS定時初值（T0計時用）
MOV TH0,#3CH
SETB EA ;總中斷開放
SETB ET0 ;允許T0中斷
SETB TR0 ;T0定時器開始計時
MOV R4,#14H ;1秒定時用初值（50MS×20）
START1:LCALL DISPLAY ;顯示子程序
LCALL BEEP ;鬧鍾查詢
JNB P1.7,SETTIME ;P1.7口為0時轉時間調整程序
JMP START1 ;P1.7口為1時跳回START1
;-----------------------時間鬧鍾調整系統--------------------------;
NFLAG:MOV A,68H ;設置鬧鍾開關狀態
CJNE A,#1,BEE68
MOV 68H,#0
JMP E6
BEE68:MOV 68H,#1
E6:MOV 66H,#8 ;中斷退出66H不為1時分、時計時單元數據移入顯存標志
MOV 72H,7BH
MOV 73H,7CH
MOV 74H,7DH
MOV 75H,7EH
LCALL DDL
LCALL DDL
MOV 72H,68H
MOV 73H,69H
MOV 74H,7AH
MOV 75H,7AH
LCALL DDL
LCALL DDL
MOV 66H,#1
LJMP START1
SETTIME:LCALL DDL
JB P1.7,NFLAG ;鍵按下時間小於1秒，設置鬧鍾開關狀態並查看鬧鍾時間,不關走時,確保准確,大於1秒調時
MOV TL1,#0B0H ;T1閃爍定時初值
MOV TH1,#3CH
MOV R2,#06H ;進入調時狀態，賦閃爍定時初值
MOV 66H,#8 ;調鬧鍾時保持走時,關閉時鍾顯示數據
SETB ET1 ;允許T1中斷
SETB TR1 ;開啟定時器T1
SET1:LCALL DISPLAY ;調用顯示,防止鍵按下無顯示
JNB P1.7,SET1 ;P1.7口為0等待鍵釋放
MOV R5,#00H ;清設置類型閃爍標志
SETN1:INC R5 ;鬧鍾分調整
SET5:LCALL DISPLAY
JB P1.7,SET5
SEETN1:LCALL DDL ;有鍵按下大於1秒分時間連續加(0.5秒加1),小於1秒轉調時狀態
JB P1.7,SET6 ;鍵釋放查詢,鍵釋放自動轉調時
MOV R0,#7CH
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#60H,HHN1
HHN1:JC SEETN1
LCALL CLR0
JMP SEETN1
SET6:INC R5 ;鬧鍾時調整
SEET6:LCALL DISPLAY
JB P1.7,SEET6
SEETNH1:LCALL DDL
JB P1.7,SETF
MOV R0,#7EH
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#24H,HOUU1
HOUU1:JC SEETNH1
LCALL CLR0
JMP SEETNH1
SETF:LCALL DISPLAY
JB P1.7,SETF
LCALL DDL
JNB P1.7,SETOUT ;短按調時,長按退出
CLR ET0
CLR TR0
MOV 70H,#00H ;設定後的時間從00秒開始走時
MOV 71H,#00H
INC R5
SET3:LCALL DISPLAY
JB P1.7,SET3
SETMM:LCALL DDL
JB P1.7,SET4
MOV R0,#77H
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#60H,MMH
MMH:JC SETMM
LCALL CLR0
AJMP SETMM
SET4:INC R5
SEET4:LCALL DISPLAY
JB P1.7,SEET4
SETHH:LCALL DDL
JB P1.7,SETOUT1
MOV R0,#79H
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#24H,HOUU
HOUU:JC SETHH
LCALL CLR0
AJMP SETHH
SETOUT1:SETB ET0
SETB TR0 ;計時開始
SETOUT:MOV R5,#00H ;清設置類型閃爍標志
CLR TR1 ;關閉T1
CLR ET1 ;關T1中斷
MOV 66H,#1
SETOUT2:LCALL DISPLAY
JNB P1.7,SETOUT2
LJMP START1
;--------------------------延時1秒鍾-----------------------;
DDL:MOV 18H,#36
DDL0:MOV 17H,#239
DDL1:LCALL DISPLAY
DJNZ 17H,DDL1
DJNZ 18H,DDL0
RET
;----------------------------T0中斷程序------------------------;
INTT0: PUSH ACC ;打包
PUSH PSW
CLR ET0
CLR TR0
MOV A,#0B7H
ADD A,TL0
MOV TL0,A
MOV A,#3CH
ADDC A,TH0
MOV TH0,A
SETB TR0
DJNZ R4, OUTT0 ;20次中斷未到中斷退出
ADDSS: MOV R4,#14H ;20次中斷到（1秒）重賦初值
MOV R0,#71H ;指向秒計時單元（70-71H）
ACALL ADD1 ;調用加1程序（加1秒操作）
MOV A,R3 ;秒數據放入A（R3為2位十進制數組合）
CLR C ;清進位標志
CJNE A,#60H,ADDMM
ADDMM: JC OUTT01 ;小於60秒退出
ACALL CLR0 ;等於或大於60秒清0
MOV R0,#77H ;指向分計時單元（76H-77H）
ACALL ADD1
MOV A,R3
CLR C
CJNE A,#60H,ADDHH
ADDHH: JC OUTT0
ACALL CLR0
MOV R0,#79H ;指向小時計時單元（78H-79H）
ACALL ADD1
MOV A,R3
CLR C
CJNE A,#24H,HOUR
HOUR: JC OUTT0
ACALL CLR0
OUTT0: MOV A,66H ;查詢標志
CJNE A,#1,OUTT01
MOV 72H,76H ;中斷退出時將分、時計時單元數據移入對應顯示單元
MOV 73H,77H
MOV 74H,78H
MOV 75H,79H
OUTT01:POP PSW ;出棧
POP ACC
SETB ET0 ;開放T0
RETI ;中斷返回
;---------------------------加1程序--------------------------;
ADD1: MOV A,@R0 ;取當前計時單元數據到A
DEC R0 ;指向前一地址
SWAP A ;A中數據高四位與低四位交換
ORL A,@R0 ;前一地址中數據放入A中低四位
ADD A,#01H ;A加1操作
DA A ;十進制調整
MOV R3,A ;移入R3寄存器
ANL A,#0FH ;高四位變0
MOV @R0,A ;放回前一地址單元
MOV A,R3 ;取回R3中暫存數據
INC R0 ;指向當前地址單元
SWAP A ;A中數據高四位與低四位交換
ANL A,#0FH ;高四位變0
MOV @R0,A ;數據放入當削地址單元中
RET
CLR0: CLR C
CLR A ;清累加器
MOV @R0,A ;清當前地址單元
DEC R0 ;指向前一地址
MOV @R0,A ;前一地址單元清0
RET ;子程序返回
;-------------------------調時閃爍程序----------------------;
INTT1: PUSH ACC
PUSH PSW
MOV TL1,#0B0H
MOV TH1,#3CH
DJNZ R2,INTT1OUT ;0.3秒未到退出中斷（50MS中斷6次）
MOV R2,#06H ;重裝0.3秒定時用初值
CPL 02H ;0.3秒定時到對閃爍標志取反
JB 02H,FLASH1 ;02H位為1時顯示單元"熄滅"
MOV A,R5
CJNE A,#01H,NL
JMP NNN1
NL:CJNE A,#02H,NL1
LJMP NNN1
NL1:CJNE A,#03H,NL2
LJMP NLL
NL2:CJNE A,#04H,INTT1OUT
LJMP NLL
NLL:MOV 72H,76H
MOV 73H,77H
MOV 74H,78H
MOV 75H,79H
AJMP INTT1OUT
NNN1:MOV 72H,7BH
MOV 73H,7CH
MOV 74H,7DH
MOV 75H,7EH
INTT1OUT:POP PSW ;恢復現場
POP ACC
RETI ;中斷退出
FLASH1:MOV A,R5
CJNE A,#01H,ML
LJMP MNN1
ML:CJNE A,#02H,ML1
LJMP MNN2
ML1:CJNE A,#03H,MN
LJMP MLL
MN:CJNE A,#04H,INTT1OUT
LJMP MHL
MLL:MOV 72H,7AH
MOV 73H,7AH ;顯示單元（72-73H），將不顯示分數據
MOV 74H,78H
MOV 75H,79H
AJMP INTT1OUT
MHL:MOV 72H,76H
MOV 73H,77H
MOV 74H,7AH ;顯示單元（74-75H），小時數據將不顯示
MOV 75H,7AH
AJMP INTT1OUT
MNN1:MOV 72H,7AH
MOV 73H,7AH ;顯示單元（72-73H），將不顯示鬧鍾分數據
MOV 74H,7DH
MOV 75H,7EH
AJMP INTT1OUT
MNN2:MOV 72H,7BH
MOV 73H,7CH
MOV 74H,7AH
MOV 75H,7AH ;顯示單元（74-75H），鬧鍾小時數據將不顯示
AJMP INTT1OUT
;-------------------------顯示-------------------------------;
DISPLAY:MOV DPTR,#DISDATA
MOV A,70H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.0
NOP
NOP
NOP
SETB P1.0
MOV A,71H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.1
NOP
NOP
NOP
SETB P1.1
MOV A,72H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.2
NOP
NOP
NOP
SETB P1.2
MOV A,73H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.3
NOP
NOP
NOP
SETB P1.3
MOV A,74H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.4
NOP
NOP
NOP
SETB P1.4
MOV A,75H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.5
NOP
NOP
NOP
SETB P1.5
RET
BEEP:MOV A,68H ;查詢標志
CJNE A,#1,BEERE
MOV A,78H ;查詢鬧鍾時個位
CJNE A,7DH,BEERE
MOV A,79H ;查詢鬧鍾時十位
CJNE A,7EH,BEERE
MOV A,76H ;查詢鬧鍾分個位
CJNE A,7BH,BEERE
MOV A,77H ;查詢鬧鍾分十位
CJNE A,7CH,BEERE
BB:CLR P1.6
LCALL DDL
SETB P1.6
LCALL DDL
JNB P1.7,BEERR
BEERE:RET
BEERR:SETB P1.6
MOV 68H,#0
LCALL DISPLAY
JNB P1.7,BEERR
JMP BEERE
DISDATA:DB 0C0H,0F9H,64H,70H,59H,52H,42H,0F8H,40H,50H,0FFH ;0123456789空白
END
⑵ 單片機電子鍾原理圖，幫我大概解釋一下這個圖的工作原理就可以了，謝謝。帶圖！5分
本電子鍾採用PIC16C55單片機控制，適於溫室的定時恆溫或自來水的定時定壓控制等。PIC16C55單片機工作電壓為2.5～6.25V，功耗低、驅動能力強。本電子鍾可以控制一路負載在24小時內的3次開/關;一個雙限觸發的定時輸出口，既可接傳統的功率保持型繼電器，也可接脈沖繼電器。本機用四位LED數碼管掃描式顯示，還有消隱(省電)工作方式，使用起來非常靈活、方便。
一、 電子鍾工作原理
電子鍾電路見圖1。RB7口是定時指示端，在定時開期間輸出高電平，驅動V1發光，該口也可經緩沖作定時輸出口;RB6是雙限觸發控制的定時輸出口，其工作方式是：在RB7高電平期間，若RB1為高電平，則RB6輸出高電平;若RB0為高電平，RB6輸出低電平;若RB1、RB0同為低電平，RB6保持原態; 同為高電平時，RB6輸出低電平。RB5、RB4用於驅動脈沖繼電器，RB6上升沿觸發RB5輸出高電平開脈沖;在RB6下降沿觸發RB4時，RB4端輸出高電平關脈沖，開/關脈沖的持續時間均為125ms。
圖 1
RB3是消隱控制器，接高電平(即SK1閉合)時，顯示屏及秒閃正常;否則，顯示消隱。顯示消隱時，時鍾及各控制邏輯都正常運行，如忽略RB4至RB7各口的驅動電流，則在3V供電時，整機電流不足20μA，即兩節5號電池可用數月!RB2選擇數碼管極性，RB2為低電平，使用共陰LED;RB2為高電平，則用共陽LED。數碼管的極性是在上電初始化時，根據 RB2口狀態確定的，工作過程中改變RB2的電平則不起作用。
本機設S1～S4四個按鍵，S1是功能選擇鍵，S2是小時增量調整，S3是分鍾增量，S4用於分鍾減量調節，其使用方法為：
上電時，RB5至RB7均為低電平，RB4端送出一個關脈沖，使SK1閉合，整機正常顯示、工作，RC7口送出秒閃脈沖，RC6～RC0送欄位碼。RA3～RA0分別為10時、時、10分、分位的位碼輸出。這時，按一下S2或S3(時增量/ 分增量鍵)，可使RB7端置位或復位。
在正常走時期間，秒閃正常;在校對或設置定時時，秒停閃。例如：在正常走時期間，按一下S1鍵，秒閃停止，屏幕顯示J-，表示可以校對時間。這時再按S2～S4中任一鍵，屏幕顯示現在時間，但秒不閃，此刻可按S2～S4校對時鍾。再次按S1，屏幕顯示 1∪，表示可以設定第一次開時間，此時按S2～S4對時間進行查看及設置。繼續按S1，系統顯示1∩，表示可設置第一次關時間……依次進行。設置好系統及 3次開關時間後，整機回到正常顯示狀態，秒閃恢復。
如欲取消某次開/關定時，只需把該次的開與關時間設置成相同值即可。
筆者曾把該時鍾用於定時定壓供水控制系統，RB6端用於驅動繼電器(也可用RB5與RB4兩端驅動脈沖繼電器)，RB1端接水壓(水位)的低限輸入，RB0 端接高限輸入，設置好定時，一個簡易的定時定壓自動供水系統即告完成。
二、 編程技巧
PIC16C55單片機程序存儲器只有512位元組，加上採用外接32768Hz晶體振盪方式，時鍾速度較低，因此，統籌好系統的工作時序與人機界面之間的關系是軟體設計成敗的關鍵。本機編程採用如下方案：軟體工作流程見附圖2。
圖 2
PIC16C55單片機的一個機器周期是4個時鍾周期，不難算出，本系統中每秒有8192個機器周期。在編制軟體時，先設定單片機內部定時計數器F1的計數方式為機器周期的64分頻。這樣，每當F1溢出時，系統遞加2秒。平時，系統每128個機器周期內用RC口與RA口驅動掃描一次顯示屏，可保證每秒內掃描64次顯示屏，基本上無閃爍感。而 128個機器周期正是F1的第0位(為便於敘述以下簡記為F1?0)每次下降沿的間隔時間，我們可以編一段程序，當F1?0的下降沿到來時，掃描一次顯示屏，每當F1的低4位為全0時(125ms一次)使系統檢測一次RB口與按鍵狀態，並進行相關處理，部分相關程序如下：
WAIT BTFSC 1，0 ;等待F1?0的下降沿，編程時
GOTO WAIT ;要保證每次下降沿前到此
MOVFW 1
SKPNZ
GOTO CLOCK ;F1=0，滿2秒，轉時鍾處理
ANDLW 0FH ;屏蔽F1高4位
SKPZ
GOTO DISPLAY;F1低4位不為0，轉顯示
MOVLW 0C0H ;滿125mS，使RB口脈沖復位
ANDWF 6，1
MOVLW 0FH ;檢測按鍵
TRIS 7
MOVFW 7
ANDLW 0FH ;保留按鍵數據
SKPZ
GOTO AN;有鍵值，轉按鍵處理
DISPLAY …… ;顯示掃描，定時管理RB口
CLOCK …… ;時鍾，定時處理程序
AN …… ;按鍵管理程序