⑴ 51单片机做数字电子钟
源程序如下： ORG 0000H ;程序开始入口
LJMP START
ORG 0003H ;外中断0中断程序入口
RETI
ORG 000BH ;定时器T0中断程序入口
LJMP INTT0 ;跳至INTTO执行
ORG 0013H ;外中断1中断程序入口
RETI
ORG 001BH ;定时器T1中断程序入口
LJMP INTT1
ORG 0023H ;串行中断程序入口地址
RETI
;---------------主程序----------------------;
START:MOV R0,#70H ;70给R0,清70-7FH显示内存
MOV R7,#0FH
CLEARDISP:MOV @R0,#00H ;0给R0中的数为地址的内存中存放(70H)
INC R0
DJNZ R7,CLEARDISP
MOV 78H,#2 ;默认时间为12:00,闹钟5:00
MOV 79H,#1
MOV 74H,#2 ;防止上电时数码管显示00小时
MOV 75H,#1
MOV 66H,#1 ;中断退出时66H为1时,分、时计时单元数据移入显存标志
MOV 68H,#1 ;上电默认闹钟开状态
MOV 7DH,#6 ;闹钟时十位
MOV 7CH,#3
MOV 69H,#0
MOV 7AH,#0AH ;放入"熄灭符"数据
MOV TMOD,#11H ;设T0、T1为16位定时器
MOV TL0,#0B0H ;50MS定时初值（T0计时用）
MOV TH0,#3CH
SETB EA ;总中断开放
SETB ET0 ;允许T0中断
SETB TR0 ;T0定时器开始计时
MOV R4,#14H ;1秒定时用初值（50MS×20）
START1:LCALL DISPLAY ;显示子程序
LCALL BEEP ;闹钟查询
JNB P1.7,SETTIME ;P1.7口为0时转时间调整程序
JMP START1 ;P1.7口为1时跳回START1
;-----------------------时间闹钟调整系统--------------------------;
NFLAG:MOV A,68H ;设置闹钟开关状态
CJNE A,#1,BEE68
MOV 68H,#0
JMP E6
BEE68:MOV 68H,#1
E6:MOV 66H,#8 ;中断退出66H不为1时分、时计时单元数据移入显存标志
MOV 72H,7BH
MOV 73H,7CH
MOV 74H,7DH
MOV 75H,7EH
LCALL DDL
LCALL DDL
MOV 72H,68H
MOV 73H,69H
MOV 74H,7AH
MOV 75H,7AH
LCALL DDL
LCALL DDL
MOV 66H,#1
LJMP START1
SETTIME:LCALL DDL
JB P1.7,NFLAG ;键按下时间小于1秒，设置闹钟开关状态并查看闹钟时间,不关走时,确保准确,大于1秒调时
MOV TL1,#0B0H ;T1闪烁定时初值
MOV TH1,#3CH
MOV R2,#06H ;进入调时状态，赋闪烁定时初值
MOV 66H,#8 ;调闹钟时保持走时,关闭时钟显示数据
SETB ET1 ;允许T1中断
SETB TR1 ;开启定时器T1
SET1:LCALL DISPLAY ;调用显示,防止键按下无显示
JNB P1.7,SET1 ;P1.7口为0等待键释放
MOV R5,#00H ;清设置类型闪烁标志
SETN1:INC R5 ;闹钟分调整
SET5:LCALL DISPLAY
JB P1.7,SET5
SEETN1:LCALL DDL ;有键按下大于1秒分时间连续加(0.5秒加1),小于1秒转调时状态
JB P1.7,SET6 ;键释放查询,键释放自动转调时
MOV R0,#7CH
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#60H,HHN1
HHN1:JC SEETN1
LCALL CLR0
JMP SEETN1
SET6:INC R5 ;闹钟时调整
SEET6:LCALL DISPLAY
JB P1.7,SEET6
SEETNH1:LCALL DDL
JB P1.7,SETF
MOV R0,#7EH
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#24H,HOUU1
HOUU1:JC SEETNH1
LCALL CLR0
JMP SEETNH1
SETF:LCALL DISPLAY
JB P1.7,SETF
LCALL DDL
JNB P1.7,SETOUT ;短按调时,长按退出
CLR ET0
CLR TR0
MOV 70H,#00H ;设定后的时间从00秒开始走时
MOV 71H,#00H
INC R5
SET3:LCALL DISPLAY
JB P1.7,SET3
SETMM:LCALL DDL
JB P1.7,SET4
MOV R0,#77H
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#60H,MMH
MMH:JC SETMM
LCALL CLR0
AJMP SETMM
SET4:INC R5
SEET4:LCALL DISPLAY
JB P1.7,SEET4
SETHH:LCALL DDL
JB P1.7,SETOUT1
MOV R0,#79H
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#24H,HOUU
HOUU:JC SETHH
LCALL CLR0
AJMP SETHH
SETOUT1:SETB ET0
SETB TR0 ;计时开始
SETOUT:MOV R5,#00H ;清设置类型闪烁标志
CLR TR1 ;关闭T1
CLR ET1 ;关T1中断
MOV 66H,#1
SETOUT2:LCALL DISPLAY
JNB P1.7,SETOUT2
LJMP START1
;--------------------------延时1秒钟-----------------------;
DDL:MOV 18H,#36
DDL0:MOV 17H,#239
DDL1:LCALL DISPLAY
DJNZ 17H,DDL1
DJNZ 18H,DDL0
RET
;----------------------------T0中断程序------------------------;
INTT0: PUSH ACC ;打包
PUSH PSW
CLR ET0
CLR TR0
MOV A,#0B7H
ADD A,TL0
MOV TL0,A
MOV A,#3CH
ADDC A,TH0
MOV TH0,A
SETB TR0
DJNZ R4, OUTT0 ;20次中断未到中断退出
ADDSS: MOV R4,#14H ;20次中断到（1秒）重赋初值
MOV R0,#71H ;指向秒计时单元（70-71H）
ACALL ADD1 ;调用加1程序（加1秒操作）
MOV A,R3 ;秒数据放入A（R3为2位十进制数组合）
CLR C ;清进位标志
CJNE A,#60H,ADDMM
ADDMM: JC OUTT01 ;小于60秒退出
ACALL CLR0 ;等于或大于60秒清0
MOV R0,#77H ;指向分计时单元（76H-77H）
ACALL ADD1
MOV A,R3
CLR C
CJNE A,#60H,ADDHH
ADDHH: JC OUTT0
ACALL CLR0
MOV R0,#79H ;指向小时计时单元（78H-79H）
ACALL ADD1
MOV A,R3
CLR C
CJNE A,#24H,HOUR
HOUR: JC OUTT0
ACALL CLR0
OUTT0: MOV A,66H ;查询标志
CJNE A,#1,OUTT01
MOV 72H,76H ;中断退出时将分、时计时单元数据移入对应显示单元
MOV 73H,77H
MOV 74H,78H
MOV 75H,79H
OUTT01:POP PSW ;出栈
POP ACC
SETB ET0 ;开放T0
RETI ;中断返回
;---------------------------加1程序--------------------------;
ADD1: MOV A,@R0 ;取当前计时单元数据到A
DEC R0 ;指向前一地址
SWAP A ;A中数据高四位与低四位交换
ORL A,@R0 ;前一地址中数据放入A中低四位
ADD A,#01H ;A加1操作
DA A ;十进制调整
MOV R3,A ;移入R3寄存器
ANL A,#0FH ;高四位变0
MOV @R0,A ;放回前一地址单元
MOV A,R3 ;取回R3中暂存数据
INC R0 ;指向当前地址单元
SWAP A ;A中数据高四位与低四位交换
ANL A,#0FH ;高四位变0
MOV @R0,A ;数据放入当削地址单元中
RET
CLR0: CLR C
CLR A ;清累加器
MOV @R0,A ;清当前地址单元
DEC R0 ;指向前一地址
MOV @R0,A ;前一地址单元清0
RET ;子程序返回
;-------------------------调时闪烁程序----------------------;
INTT1: PUSH ACC
PUSH PSW
MOV TL1,#0B0H
MOV TH1,#3CH
DJNZ R2,INTT1OUT ;0.3秒未到退出中断（50MS中断6次）
MOV R2,#06H ;重装0.3秒定时用初值
CPL 02H ;0.3秒定时到对闪烁标志取反
JB 02H,FLASH1 ;02H位为1时显示单元"熄灭"
MOV A,R5
CJNE A,#01H,NL
JMP NNN1
NL:CJNE A,#02H,NL1
LJMP NNN1
NL1:CJNE A,#03H,NL2
LJMP NLL
NL2:CJNE A,#04H,INTT1OUT
LJMP NLL
NLL:MOV 72H,76H
MOV 73H,77H
MOV 74H,78H
MOV 75H,79H
AJMP INTT1OUT
NNN1:MOV 72H,7BH
MOV 73H,7CH
MOV 74H,7DH
MOV 75H,7EH
INTT1OUT:POP PSW ;恢复现场
POP ACC
RETI ;中断退出
FLASH1:MOV A,R5
CJNE A,#01H,ML
LJMP MNN1
ML:CJNE A,#02H,ML1
LJMP MNN2
ML1:CJNE A,#03H,MN
LJMP MLL
MN:CJNE A,#04H,INTT1OUT
LJMP MHL
MLL:MOV 72H,7AH
MOV 73H,7AH ;显示单元（72-73H），将不显示分数据
MOV 74H,78H
MOV 75H,79H
AJMP INTT1OUT
MHL:MOV 72H,76H
MOV 73H,77H
MOV 74H,7AH ;显示单元（74-75H），小时数据将不显示
MOV 75H,7AH
AJMP INTT1OUT
MNN1:MOV 72H,7AH
MOV 73H,7AH ;显示单元（72-73H），将不显示闹钟分数据
MOV 74H,7DH
MOV 75H,7EH
AJMP INTT1OUT
MNN2:MOV 72H,7BH
MOV 73H,7CH
MOV 74H,7AH
MOV 75H,7AH ;显示单元（74-75H），闹钟小时数据将不显示
AJMP INTT1OUT
;-------------------------显示-------------------------------;
DISPLAY:MOV DPTR,#DISDATA
MOV A,70H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.0
NOP
NOP
NOP
SETB P1.0
MOV A,71H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.1
NOP
NOP
NOP
SETB P1.1
MOV A,72H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.2
NOP
NOP
NOP
SETB P1.2
MOV A,73H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.3
NOP
NOP
NOP
SETB P1.3
MOV A,74H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.4
NOP
NOP
NOP
SETB P1.4
MOV A,75H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.5
NOP
NOP
NOP
SETB P1.5
RET
BEEP:MOV A,68H ;查询标志
CJNE A,#1,BEERE
MOV A,78H ;查询闹钟时个位
CJNE A,7DH,BEERE
MOV A,79H ;查询闹钟时十位
CJNE A,7EH,BEERE
MOV A,76H ;查询闹钟分个位
CJNE A,7BH,BEERE
MOV A,77H ;查询闹钟分十位
CJNE A,7CH,BEERE
BB:CLR P1.6
LCALL DDL
SETB P1.6
LCALL DDL
JNB P1.7,BEERR
BEERE:RET
BEERR:SETB P1.6
MOV 68H,#0
LCALL DISPLAY
JNB P1.7,BEERR
JMP BEERE
DISDATA:DB 0C0H,0F9H,64H,70H,59H,52H,42H,0F8H,40H,50H,0FFH ;0123456789空白
END
⑵ 单片机电子钟原理图，帮我大概解释一下这个图的工作原理就可以了，谢谢。带图！5分
本电子钟采用PIC16C55单片机控制，适于温室的定时恒温或自来水的定时定压控制等。PIC16C55单片机工作电压为2.5～6.25V，功耗低、驱动能力强。本电子钟可以控制一路负载在24小时内的3次开/关;一个双限触发的定时输出口，既可接传统的功率保持型继电器，也可接脉冲继电器。本机用四位LED数码管扫描式显示，还有消隐(省电)工作方式，使用起来非常灵活、方便。
一、 电子钟工作原理
电子钟电路见图1。RB7口是定时指示端，在定时开期间输出高电平，驱动V1发光，该口也可经缓冲作定时输出口;RB6是双限触发控制的定时输出口，其工作方式是：在RB7高电平期间，若RB1为高电平，则RB6输出高电平;若RB0为高电平，RB6输出低电平;若RB1、RB0同为低电平，RB6保持原态; 同为高电平时，RB6输出低电平。RB5、RB4用于驱动脉冲继电器，RB6上升沿触发RB5输出高电平开脉冲;在RB6下降沿触发RB4时，RB4端输出高电平关脉冲，开/关脉冲的持续时间均为125ms。
图 1
RB3是消隐控制器，接高电平(即SK1闭合)时，显示屏及秒闪正常;否则，显示消隐。显示消隐时，时钟及各控制逻辑都正常运行，如忽略RB4至RB7各口的驱动电流，则在3V供电时，整机电流不足20μA，即两节5号电池可用数月!RB2选择数码管极性，RB2为低电平，使用共阴LED;RB2为高电平，则用共阳LED。数码管的极性是在上电初始化时，根据 RB2口状态确定的，工作过程中改变RB2的电平则不起作用。
本机设S1～S4四个按键，S1是功能选择键，S2是小时增量调整，S3是分钟增量，S4用于分钟减量调节，其使用方法为：
上电时，RB5至RB7均为低电平，RB4端送出一个关脉冲，使SK1闭合，整机正常显示、工作，RC7口送出秒闪脉冲，RC6～RC0送字段码。RA3～RA0分别为10时、时、10分、分位的位码输出。这时，按一下S2或S3(时增量/ 分增量键)，可使RB7端置位或复位。
在正常走时期间，秒闪正常;在校对或设置定时时，秒停闪。例如：在正常走时期间，按一下S1键，秒闪停止，屏幕显示J-，表示可以校对时间。这时再按S2～S4中任一键，屏幕显示现在时间，但秒不闪，此刻可按S2～S4校对时钟。再次按S1，屏幕显示 1∪，表示可以设定第一次开时间，此时按S2～S4对时间进行查看及设置。继续按S1，系统显示1∩，表示可设置第一次关时间……依次进行。设置好系统及 3次开关时间后，整机回到正常显示状态，秒闪恢复。
如欲取消某次开/关定时，只需把该次的开与关时间设置成相同值即可。
笔者曾把该时钟用于定时定压供水控制系统，RB6端用于驱动继电器(也可用RB5与RB4两端驱动脉冲继电器)，RB1端接水压(水位)的低限输入，RB0 端接高限输入，设置好定时，一个简易的定时定压自动供水系统即告完成。
二、 编程技巧
PIC16C55单片机程序存储器只有512字节，加上采用外接32768Hz晶体振荡方式，时钟速度较低，因此，统筹好系统的工作时序与人机界面之间的关系是软件设计成败的关键。本机编程采用如下方案：软件工作流程见附图2。
图 2
PIC16C55单片机的一个机器周期是4个时钟周期，不难算出，本系统中每秒有8192个机器周期。在编制软件时，先设定单片机内部定时计数器F1的计数方式为机器周期的64分频。这样，每当F1溢出时，系统递加2秒。平时，系统每128个机器周期内用RC口与RA口驱动扫描一次显示屏，可保证每秒内扫描64次显示屏，基本上无闪烁感。而 128个机器周期正是F1的第0位(为便于叙述以下简记为F1?0)每次下降沿的间隔时间，我们可以编一段程序，当F1?0的下降沿到来时，扫描一次显示屏，每当F1的低4位为全0时(125ms一次)使系统检测一次RB口与按键状态，并进行相关处理，部分相关程序如下：
WAIT BTFSC 1，0 ;等待F1?0的下降沿，编程时
GOTO WAIT ;要保证每次下降沿前到此
MOVFW 1
SKPNZ
GOTO CLOCK ;F1=0，满2秒，转时钟处理
ANDLW 0FH ;屏蔽F1高4位
SKPZ
GOTO DISPLAY;F1低4位不为0，转显示
MOVLW 0C0H ;满125mS，使RB口脉冲复位
ANDWF 6，1
MOVLW 0FH ;检测按键
TRIS 7
MOVFW 7
ANDLW 0FH ;保留按键数据
SKPZ
GOTO AN;有键值，转按键处理
DISPLAY …… ;显示扫描，定时管理RB口
CLOCK …… ;时钟，定时处理程序
AN …… ;按键管理程序